(05-03-20, 11:17 PM)ابو روضة كتب :

السلام عليكم  ورحمة الله وبركاته..

اخوتى لدى كود عرض صورة داخل اداه PictureBox بحيث اضع مسار الصورة فى التكست بوكس

ومن ثم أضغط على الزر ليعرضها لى داخل الاداه وما اريده هو اضافة زر التالى وزر السابق بحيث

لما اضغط مثلا على زر التالى يعرض الصورة التالية الموجودة بنفس المسار اللى فى التكست بوكس بود

وضع المسار داخل التكست بوكس.. فهل هناك كود يقوم بهذا ؟

وجزاكم الله كل خير.

كود :

PictureBox1.ImageLocation = TextBox1.Text

وقد قمت بمشاهدة هذا الموضوع لكن لم تنجح الطريقة معى

http://vb4arb.com/vb/showthread.php?tid=25790        

(05-03-20, 11:58 PM)ابراهيم ايبو كتب : السلام عليكم اخي الغالي ابو روضة
تفضل هذه اكواد زر التحميل وزر سابق  وتالي

كود :

' تعريف لائحة لنضع فيها اسماء الصور الموجودة في المجلد الذي سنختاره
   Dim Filenames As List(Of String) = New List(Of String)
   Dim Counter As Integer = 0 ' تعريف متغير رقمي

   Private Sub Btn_LoadPicture_Click(sender As Object, e As EventArgs) Handles Btn_LoadPicture.Click
       Dim fbd As New FolderBrowserDialog()
       If fbd.ShowDialog() = DialogResult.OK Then
           Filenames.AddRange(System.IO.Directory.GetFiles(fbd.SelectedPath, "*.jpg")) ' اضافة الصور من نوع جيبك
           If Filenames.Count > 1 Then PictureBox1.Load(Filenames(Counter)) ' تحميل الصورة رقم الكونتر صفر
       End If
   End Sub

   Private Sub Btn_Next_Click(sender As Object, e As EventArgs) Handles Btn_Next.Click
       If Counter < Filenames.Count - 1 Then
           Counter += 1
       Else
           Counter = 0
       End If
       PictureBox1.Load(Filenames(Counter))
   End Sub

   Private Sub Btn_Previous_Click(sender As Object, e As EventArgs) Handles Btn_Previous.Click
       If Counter > 0 Then
           Counter -= 1
       Else
           Counter = Filenames.Count - 1
       End If
       PictureBox1.Load(Filenames(Counter))
   End Sub

(06-03-20, 12:01 AM)alsalamoni كتب :

كود :

Public Class Form1

   'Images list
   Dim images As New List(Of String)
   'Current index
   Dim index As Integer = -1

   'GetFiles
   Private Sub ButtonGetFiles_Click(sender As Object, e As EventArgs) Handles ButtonGetFiles.Click
       Dim dir As String = Environment.GetFolderPath(Environment.SpecialFolder.MyPictures) '"C:\....."
       'Using FolderBrowserDialog1 As New FolderBrowserDialog
       '    If FolderBrowserDialog1.ShowDialog = DialogResult.OK Then
       '        dir = FolderBrowserDialog1.SelectedPath
       '    End If
       'End Using
       images.Clear()
       index = -1
       images.AddRange(IO.Directory.GetFiles(dir, "*.png"))
       images.AddRange(IO.Directory.GetFiles(dir, "*.jpg"))
       ButtonNext.PerformClick()
   End Sub

   'Prev
   Private Sub ButtonPrev_Click(sender As Object, e As EventArgs) Handles ButtonPrev.Click
       If index > 0 Then
           index -= 1
           PictureBox1.ImageLocation = images(index)
       End If
   End Sub

   'Next
   Private Sub ButtonNext_Click(sender As Object, e As EventArgs) Handles ButtonNext.Click
       If index < images.Count - 1 Then
           index += 1
           PictureBox1.ImageLocation = images(index)
       End If
   End Sub

End Class

---

هذا الكود من احد المشاريع التي اهدانيها احد المبرمجين قديما